rails y más cosas » actionscript

Movimiento de Objetos en ActionScript 3.0

admin — Fri, 25 Jul 2008 20:59:55 +0000

Mediante la clase Timer podemos establecer un intervalo de llamada a una función para desarrollo de una acción, de una forma continuada.

 
package 
{
	import flash.display.Sprite;
	import flash.events.TimerEvent;
	import flash.utils.Timer;
	import flash.events.Event;
 
 
	/**
	* ...
	* @author DefaultUser (Tools -> Custom Arguments...)
	*/
	public class Moviendo1 extends Sprite 
	{
		//creacion del movieclip 
		private var _elemento: Sprite;
		private var _velocidadx:Number = 5;
		private var _velocidady:Number = 3;
		private var _intervalo :Timer;
 
 
		public function Moviendo1( )
		{   
 
			_elemento = new Sprite();
			_intervalo = new Timer(20);
 
 
			_elemento.graphics.beginFill(0x0000ff, 100);
			_elemento.graphics.drawCircle (0, 0, 25);
			_elemento.graphics.endFill();
 
			//posición inicial
 
			_elemento.x = 20;
			_elemento.y = 20;
 
			//añadimos el elemento a la lista 
 
 
			_intervalo.addEventListener("timer", desplazar);
			_intervalo.start();
 
		    addChild(_elemento);
 
 
 
		}
 
		private function desplazar( evento : TimerEvent ):void
		{    //establecemos la velocidad de movimiento
			_elemento.x += _velocidadx;
			_elemento.y += _velocidady;
		  // 500 es el ancho de la aplicacion y 400 la altura	
		    if ((_elemento.x >= 500 ) || (_elemento.y >= 400))
			{
				_elemento.x = 20;
				_elemento.y = 20;
			}
		}
 
 
 
	}
 
}

Botones en actionscript 3.0

admin — Thu, 24 Jul 2008 16:49:50 +0000

Tenemos un método crearCirculo al que se le pasa un entero sin signo, y el radio para la creación del círculo, dicho método devuelve una forma.
Para la creacíon del botón utilizamos la clase SimpleButton y creamos una instancia de dicha clase
var boton:SimpleButton = new SimpleButton();

El botón se asocia a diferentes formas según su estado y se establece el area activa del botón a un estado inicial, finalmente se vincula el botón a un evento del mouse.

 package
{
	import flash.display.SimpleButton;
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import flash.display.Shape;
 
	/**
	* ...
	* @author DefaultUser (Tools -> Custom Arguments...)
	*/
 
	public class  Botones extends Sprite
	{
		//creamos un simple boton
 
		public function Botones()
		{var boton:SimpleButton = new SimpleButton();
 
		boton.x = 20;
		boton.y = 20;
 
		boton.upState = crearCirculo(0xFFF000, 15);
		boton.overState = crearCirculo (0x00ff00,12);
		boton.downState = crearCirculo (0xCCCCFF, 12);
		boton.hitTestState = boton.upState;
		addChild(boton);
 
		boton.addEventListener(MouseEvent.CLICK, funcion);
 
		}
 
		private function funcion (event:MouseEvent):void
		{
			trace("pulsado");
		}
 
	private function crearCirculo(color:uint, radio:Number ):Shape
	{
		var forma:Shape = new Shape();
		forma.graphics.beginFill(color);
		forma.graphics.drawCircle(20, 0, radio);
		forma.graphics.endFill();
		return forma;
 
	}
 
	}
 
}

Reproducción de mp3 en ActionScript 3.0

admin — Mon, 21 Jul 2008 22:30:43 +0000

Para la reproducción de mp3 en actionscript, miramos si el medio dispone de las capacidades para su reproducción, obtenemos la ruta donde está el archivo, y establecemos un buffer con motivo que la reproducción no se corte, finalmente ponemos a funcionar la reproducción con “play”.

package
{
	import flash.display.Sprite;
	import flash.media.Sound;
	import flash.media.SoundLoaderContext;
	import flash.net.URLRequest;
	import flash.system.Capabilities;
 
	/**
	* ...
	* @author DefaultUser (Tools -> Custom Arguments...)
	*/
	public class Musica extends  Sprite
	{
		private var _sonido :Sound;
		private var _url:URLRequest;
		private var _buffer :SoundLoaderContext;
 
		public function Musica()
		{
		if(flash.system.Capabilities.hasMP3)
		{    //la ruta desde el fichero fla
			_url = new URLRequest("./sonido/frozen.mp3");
			//para establecer un buffer en sonidos grandes 5 segundos
			_buffer = new SoundLoaderContext(5000);
			_sonido = new Sound(_url, _buffer);
 
			_sonido.play( );
		}
 
		else {
			trace("no tiene sonido ");
		}
 
		}
 
	}
 
}

Carga Progresiva de una Imagen en ActionScript 3.0

admin — Sun, 20 Jul 2008 09:15:32 +0000

Mediante la clase “Loader” podemos cargar elementos externos. Para hacer un siguimiento gradual de la carga, necesitamos vincular los diferentes estados de la carga de la imagen, a un método que informa del estado, mediante “addListener”. La clase “URLrequest” es la encargada de recibir la dirección física de la imagen “path”, hay que tener en cuenta que dichas direcciones vienen expresadas en el nuevo formato de flash Cs3.

Diferentes eventos, Event.OPEN apertura, ProgressEvent.PROGRESS progreso, Event.COMPLETE cuando está completo.

package
{
	import flash.display.Loader;
	import flash.display.Sprite;
	import flash.events.*;
	import flash.net.URLLoader;
	import flash.net.URLRequest;
 
	/**
	* ...
	* @author DefaultUser (Tools -> Custom Arguments...)
	*/
	public class CargadorProgreso extends  Sprite
	{
 
		public function CargadorProgreso()
		{
		var _cargador :Loader = new Loader();
 
		_cargador.contentLoaderInfo.addEventListener(Event.OPEN, manejadorApertura);
		_cargador.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, manejadorProgreso);
		_cargador.contentLoaderInfo.addEventListener(Event.COMPLETE, manejadorCompleto);
 
		addChild(_cargador);
		_cargador.load(new URLRequest("./imagenes/neonbio.jpg"));
		}
 
	private function manejadorApertura( evento:Event ):void
	{
		trace("Abriendo ...");
	}
 
	private function manejadorProgreso( evento:ProgressEvent ):void
	{
		var porciento:Number = evento.bytesLoaded / evento.bytesTotal * 100;
		trace("porcentaje" + porciento);
	}
 
	private function manejadorCompleto( evento :Event ):void
    {
		trace ("Completo ");
	}
 
	}
 
}

Carga Simple de Imágenes con ActionScript 3.0

admin — Sat, 19 Jul 2008 07:38:27 +0000

En el siguiente post se muestra, la forma sencilla de cargar una imagen con ActionScript 3.0. Cuando tenemos que cargar una imagen, en la nueva versión, tenemos que hacer uso de la clase “Loader”, creando un objeto de dicha clase. Para realizar la carga, se necesita hacer uso del método de la clase Load, especificando el path donde tenemos alojada la imagen que queremos cargar.

package
{
	import flash.display.Loader;
	import flash.display.Sprite;
	import flash.net.URLRequest;
 
	/**
	* ...
	* @author DefaultUser (Tools -> Custom Arguments...)
	*/
	public class Cargador extends Sprite
	{
		public function Cargador()
		{
			var _cargador:Loader = new Loader();
 
			addChild(_cargador);
 
			_cargador.load(new URLRequest("./imagenes/neonbio.jpg"));
 
		}
	}
 
}

Manejo de eventos y creacion de formas en ActionScript 3.0

admin — Thu, 10 Jul 2008 16:19:47 +0000

Desarrollo de una clase en AS3, con el título de DiversosCirculos , variables en AS3 es necesario declararlas previamente con la palabra reservada “var” y especificar el tipo de dato al que pertenecen

Se declara un array de colores en hexadecimal, al ser un atributo con el ambito privado no es accesible fuera de la clase y necesitamos para su tratamiento de un método de la clase público. Que recorre el array y va posicionando cada uno de los círculos, en una posición x e y distinta segun el iterador del bucle. Una de las diferencias con AS2 es que antes teníamos elemento._x en la nueva versión se sustituye por elemento.x

Al igual que otros lenguajes de programación de alto nivel como Java y C# en AS3.0 tenemos un manejador de eventos, Antes en la versión 2.0 de AS teníamos movieclip.tipodeevento = function ( )
eso en AS3 ha cambiado por addEventListener(tipodeevento, funcionManejadoradelEvento );

Otra incorporación importante es la clase Sprite que en AS2.0 no aparecía y que en posteriores Post se comentará de forma más detallada …

Código de ejemplo DiversosCirculos.as

package
{
	import flash.display.Shape;
	import flash.display.Sprite;
	import flash.events.MouseEvent;
 
	/**
	* ...
	* @author DefaultUser (Tools -> Custom Arguments...)
	*/
 
	public class DiversosCirculos extends Sprite
	{
		private var colores:Array = [ 0xFF0000, 0x990000, 0x660000, 0x00FF00,
                          0x009900, 0x006600, 0x0000FF, 0x000099,
                          0x000066, 0xCCCCCC ];
 
		public function DiversosCirculos()
		{
			//creamos diez circulos y los colamos de forma descendente
			for ( var i:int = 0; i &lt; 10 ; i++)
			{
				var auxiliar :Shape = crearCirculo( colores[i], 20);
				auxiliar.x = (i * 15);
				auxiliar.y = (i*10) + 20;
 
				addChild(auxiliar);
			}
			this.addEventListener(MouseEvent.CLICK, cambiar);
		}
 
		private function cambiar(event:MouseEvent):void
		{
			//recuperamos el objeto en la posicion indicada mediante addChildAt(indice)
			//establecemos la profundidad
			setChildIndex( getChildAt(0), numChildren -1);
 
		}
 
		private function crearCirculo(color:uint, radio:Number ):Shape
		{
		  	var forma:Shape = new Shape();
			forma.graphics.beginFill(color);
			forma.graphics.drawCircle(20, 0, radio);
			forma.graphics.endFill();
			return forma;
 
		}
	}
 
}

Diferencias entre flash8 y flash CS3 y actionscript2 y 3 al crear proyectos

admin — Mon, 07 Jul 2008 21:04:01 +0000

Este post sirve como introducción a la programación con actionscript 3.0 y flash cs3, existen comunidades de desarrolladores en flash, que tienen un material excelente para el aprendizaje o la toma de contacto con ésta tecnología .

Pero normalmente tienen contenidos fáciles de entender para aquellas personas familiarizadas con versiones anteriores y conocimientos avanzados en POO de la versión dos. Esto puede constituir un problema para las personas que trabajan con actionscript 1.0 o diseñadores flash sin una carga fuerte de metodología de la programación.

Hay diversos factores que infuyen en la implantación de As3 y flex en los mercados laborales, y que están retrasando su desarrollo.

Para facilitar un poco las cosas, partimos de cero, la creación de un proyecto .fla en blanco, cuando compramos un libro para aprender As3, en la mayoría de los casos nos encontramos con código, pero no nos explican como introducirlo para poner a funcionar un proyecto nuevo.

En As2.0 cuando queriamos tratar un movieclip como una propiedad de una clase, con un nombre identificativo, teníamos que vincular el movieclip a un nombre identificativo

Ejemplo tenemos la clase cuadrado, seria una clase para tratamiento de un movieclip con forma de cuadrado

class Cuadrado
{
 
private cuadrado1:cuadradoMovieclip;
 
public function Cuadrado(root:Movieclip)
{
 
}
}

En la anterior imagen, estamos en la situación posterior a la creación de un movieclip, botón derecho una vez selecionado el icono del movieclip dentro de la biblioteca y en el menu contextual, seleccionar vinculación.

Normalmente tenemos nuestras clases en carpetas externas para indicar a flash que nuestro código no está en los los frames de la linea del tiempo del archivo .fla, tenemos que ir a la configuración de la publicación e indicar el path.

Para hacer referencia al movieclip se utiliza attachMovie (“nombre identificador”,”nombre variable nueva”, profundidad)

Uno de los cambios considerables de As3 es que attachMovie no existe, en su lugar aparece addChild y addChildAt.

En la vinculación en flashCS3 es necesario la existencia de una clase previamente desarrollada y configurada en la configuración de la aplicación. Si intentamos dar nombre solamente como identificador como ocurrió en los proyectos 2.0, nos aparece un mensaje indicando, que no se puede encontrar la definición de la clase, debido a que no hemos establecido, una relación entre la clase programada y el movieclip.

El path en flash Cs3 es mas extricto, el punto “.” representa el directorio actual donde se ubica el archivo de proyecto .fla swf mientras que el “..” hace referencia al padre y “/” a los subdirectorios correspondientes. Si tenemos nuestros ficheros de clases en la carpeta clases respecto nuestro proyecto fla el path sería ./clases.

Para este ejemplo tenemos una clase Main en un archivo Main.as, una diferencia con el código As2
es que, las clases pertenecen a un package, el nombre de package pueden ser elegido por el programador según sea necesario. En el constructor de la clase se crea un objeto de tipo cuadrado y se posiciona en el escenario.

package
{
	import flash.display.MovieClip;
 
	/**
	* ...
	* @author DefaultUser (Tools -> Custom Arguments...)
	*/
	public class Main extends MovieClip
	{
		private var _root:MovieClip;
		private var clip1:Cuadrado = new Cuadrado();
 
		public function Main (ruta :MovieClip)
		{
			_root = ruta;
			clip1.x = 100;
			clip1.y = 100;
 
			_root.addChild(clip1);
		}
 
	}
 
}

El contructor de la clase cuadrado muestra un mensaje por la pantalla de salida y se establece un evento de ratón asociado al método bajar, el cual se encarga de mover el movieclip hacia izquierda y reponer el movieclip a una posición inicial si la posición x del movieclip es menor o igual a 20pixels

Cuadrado.as es un ejemplo sencillo para introducirnos en el desarrollo de las nuevas aplicaciones flash

 package
{
	import flash.display.MovieClip;
	import flash.events.MouseEvent;
 
	public class Cuadrado extends MovieClip
	{
	  	//constructor de la clase
 
		public function Cuadrado()
		{
		    trace ("hola mundo"); 
 
			addEventListener (MouseEvent.MOUSE_DOWN,bajar);
		}
 
		private function bajar (event:MouseEvent):void
		{
		   if (this.x &gt; 20)
		      this.x -= 5
		   else
		       this.x = stage.width - this.width
 
		}
	}
 
}

En la pantalla de acciones, podemos insertar el código de entrada al proyecto creando una variable de la clase Main, que es la encargada de crear la variable de la clase Cuadrado